[转]简单百年历bat

1. @echo off
   
2. color 3F
   
3. mode con cols=40 lines=20
   
4. setlocal enabledelayedexpansion
   
5. set str=日一二三四五六
   
6. set sdate=%date%
   
7. 
   
8. :Main
   
9. cls&echo.
   
10. :: 日期提取、格式化与校验
    
11. for /f "tokens=1,2,3 delims=-/: " %%i in ("%sdate%") do (
    
12.     (set sy=%%i) && (set sm=%%j) && (set sd=%%k)
    
13. )
    
14. if not defined sd set sd=1
    
15. if not defined sm set sm=%sy%& set sy=%date:~0,4%
    
16. 
    
17. (set sy=0000%sy%) && (set sm=00%sm%) && (set sd=00%sd%)
    
18. (set sy=%sy:~-4%) && (set sm=%sm:~-2%) && (set sd=%sd:~-2%)
    
19. cd.
    
20. set /a y=1%sy%-10000, m=1%sm%-100, d=1%sd%-100 2>nul
    
21. if errorlevel 1 goto Error
    
22. if %y% lss 100 (
    
23.     if %y% lss 50 (set /a y+=2000) else (set /a y+=1900)
    
24.     set sy=!y!
    
25. )
    
26. if %m% lss 13 if %d% lss 32 goto Calc
    
27. 
    
28. :Error
    
29. echo.错误的日期.
    
30. pause>nul
    
31. set sdate=%date%
    
32. goto Main
    
33. 
    
34. :Calc
    
35. :: 计算每个月的天数
    
36. set days=31
    
37. for %%i in (4 6 9 11) do if %m% equ %%i set days=30
    
38. :: 计算2月份的偏差
    
39. set /a leap="^!(y%%4) & ^!(^!(y%%100)) | ^!(y%%400)"
    
40. if %m% equ 2 set /a days=28+%leap%
    
41. if %m% leq 2 (set /a y-=1& set /a m+=12)
    
42. :: 计算指定日期的星期数
    
43. set /a w=(d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1)%%7
    
44. 
    
45. echo.  %sy%年%sm%月  查询日:%sy%-%sm%-%sd%,星期!str:~%w%,1!
    
46. echo.
    
47. :: 生成月历
    
48. set /a wb=(w+35-d) %% 7, we=wb+days+1, day=1
    
49. echo.    日   一   二   三   四   五   六
    
50. echo. ━━━━━━━━━━━━━━━━━━━
    
51. set /p= <nul
    
52. for /l %%i in (0,1,37) do (
    
53.     set "temp=  "
    
54.     if %%i GTR %wb% if %%i LSS %we% (
    
55.         set temp= !day!
    
56.         set temp=!temp:~-2!
    
57.         if !d! EQU !day! set temp=★
    
58.         set /a day+=1
    
59.     )
    
60.     set /p=   !temp!<nul
    
61.     set /a "wm=(%%i+1)%%7"
    
62.     if !wm! equ 0 echo.&echo.&set /p= <nul
    
63. )
    
64. echo.
    
65. echo  ━━━━━━━━━━━━━━━━━━━
    
66. echo.  输入日期可查询当日星期并显示当月月历
    
67. echo.
    
68. set sdate=
    
69. set /p sdate=  格式如：07-02-03，[回车]退出:
    
70. if defined sdate goto Main

复制代码

将代码保存为 bat 运行即可，可查询 1950-01-01 至 2049-12-31 的日期。